Hooked up script runner for indexing

* Adds link for opening local stream

* Put conditional on correct element

lib/pinchflat/downloading/downloading_helpers.ex

@@ -16,10 +16,14 @@ defmodule Pinchflat.Downloading.DownloadingHelpers do
   alias Pinchflat.Media.MediaItem
   alias Pinchflat.Downloading.MediaDownloadWorker
 
+  alias Pinchflat.Lifecycle.UserScripts.CommandRunner, as: UserScriptRunner
+
   @doc """
   Starts tasks for downloading media for any of a sources _pending_ media items.
   Jobs are not enqueued if the source is set to not download media. This will return :ok.
 
+  You can optionally set the `kickoff_delay` option to delay when the jobs are enqueued.
+
   NOTE: this starts a download for each media item that is pending,
   not just the ones that were indexed in this job run. This should ensure
   that any stragglers are caught if, for some reason, they weren't enqueued
@@ -27,13 +31,17 @@ defmodule Pinchflat.Downloading.DownloadingHelpers do
 
   Returns :ok
   """
-  def enqueue_pending_download_tasks(%Source{download_media: true} = source) do
+  def enqueue_pending_download_tasks(source, opts \\ [])
+
+  def enqueue_pending_download_tasks(%Source{download_media: true} = source, opts) do
+    kickoff_delay = Keyword.get(opts, :kickoff_delay, 0)
+
     source
     |> Media.list_pending_media_items_for()
-    |> Enum.each(&MediaDownloadWorker.kickoff_with_task/1)
+    |> Enum.each(&MediaDownloadWorker.kickoff_with_task(&1, %{}, schedule_in: kickoff_delay))
   end
 
-  def enqueue_pending_download_tasks(%Source{download_media: false}) do
+  def enqueue_pending_download_tasks(%Source{download_media: false}, _opts) do
     :ok
   end
 
@@ -53,15 +61,18 @@ defmodule Pinchflat.Downloading.DownloadingHelpers do
   downloaded, based on the source's download settings and whether media is
   considered pending.
 
+  You can optionally set the `kickoff_delay` option to delay when the jobs are enqueued.
+
   Returns {:ok, %Task{}} | {:error, :should_not_download} | {:error, any()}
   """
-  def kickoff_download_if_pending(%MediaItem{} = media_item) do
+  def kickoff_download_if_pending(%MediaItem{} = media_item, opts \\ []) do
+    kickoff_delay = Keyword.get(opts, :kickoff_delay, 0)
     media_item = Repo.preload(media_item, :source)
 
     if media_item.source.download_media && Media.pending_download?(media_item) do
       Logger.info("Kicking off download for media item ##{media_item.id} (#{media_item.media_id})")
 
-      MediaDownloadWorker.kickoff_with_task(media_item)
+      MediaDownloadWorker.kickoff_with_task(media_item, %{}, schedule_in: kickoff_delay)
     else
       {:error, :should_not_download}
     end
@@ -98,4 +109,32 @@ defmodule Pinchflat.Downloading.DownloadingHelpers do
     |> Repo.all()
     |> Enum.map(&MediaDownloadWorker.kickoff_with_task/1)
   end
+
+  @doc """
+  Creates a media item from the attributes returned by the video backend
+  (read: yt-dlp) and runs the user script with a `media_indexed` event type.
+
+  Only runs the user script if the media item was created successfully and the media item
+  doesn't already exist in the database.
+
+  Returns {:ok, %MediaItem{}} | {:error, any()}
+  """
+  def create_media_item_and_run_script(%Source{} = source, media_attrs_struct) do
+    media_already_exists =
+      MediaQuery.new()
+      |> where(^dynamic(^MediaQuery.for_source(source) and ^MediaQuery.media_id(media_attrs_struct.media_id)))
+      |> Repo.exists?()
+
+    case Media.create_media_item_from_backend_attrs(source, media_attrs_struct) do
+      {:ok, media_item} ->
+        if !media_already_exists do
+          UserScriptRunner.run(:media_indexed, media_item)
+        end
+
+        {:ok, media_item}
+
+      err ->
+        err
+    end
+  end
 end

lib/pinchflat/fast_indexing/fast_indexing_helpers.ex

@@ -10,7 +10,6 @@ defmodule Pinchflat.FastIndexing.FastIndexingHelpers do
   use Pinchflat.Media.MediaQuery
 
   alias Pinchflat.Repo
-  alias Pinchflat.Media
   alias Pinchflat.Sources.Source
   alias Pinchflat.FastIndexing.YoutubeRss
   alias Pinchflat.Downloading.DownloadingHelpers
@@ -42,7 +41,8 @@ defmodule Pinchflat.FastIndexing.FastIndexingHelpers do
         end
       end)
 
-    DownloadingHelpers.enqueue_pending_download_tasks(source)
+    # Wait 5s before enqueuing downloads to give the post-indexing user script a chance to run
+    DownloadingHelpers.enqueue_pending_download_tasks(source, kickoff_delay: 5)
 
     Enum.filter(maybe_new_media_items, & &1)
   end
@@ -57,8 +57,8 @@ defmodule Pinchflat.FastIndexing.FastIndexingHelpers do
     url = "https://www.youtube.com/watch?v=#{media_id}"
 
     case YtDlpMedia.get_media_attributes(url) do
-      {:ok, media_attrs} ->
-        Media.create_media_item_from_backend_attrs(source, media_attrs)
+      {:ok, media_attrs_struct} ->
+        DownloadingHelpers.create_media_item_and_run_script(source, media_attrs_struct)
 
       err ->
         err

lib/pinchflat/lifecycle/user_scripts/command_runner.ex

@@ -12,6 +12,7 @@ defmodule Pinchflat.Lifecycle.UserScripts.CommandRunner do
   @behaviour UserScriptCommandRunner
 
   @event_types [
+    :media_indexed,
     :media_downloaded,
     :media_deleted
   ]

lib/pinchflat/media/media_query.ex

@@ -35,6 +35,8 @@ defmodule Pinchflat.Media.MediaQuery do
   def culling_prevented, do: dynamic([mi], mi.prevent_culling == true)
   def culled, do: dynamic([mi], not is_nil(mi.culled_at))
   def redownloaded, do: dynamic([mi], not is_nil(mi.media_redownloaded_at))
+  def media_id(nil), do: dynamic(false)
+  def media_id(media_id), do: dynamic([mi], mi.media_id == ^media_id)
 
   def upload_date_after_source_cutoff do
     dynamic([mi, source], is_nil(source.download_cutoff_date) or mi.upload_date >= source.download_cutoff_date)

lib/pinchflat/slow_indexing/slow_indexing_helpers.ex

@@ -8,7 +8,6 @@ defmodule Pinchflat.SlowIndexing.SlowIndexingHelpers do
   require Logger
 
   alias Pinchflat.Repo
-  alias Pinchflat.Media
   alias Pinchflat.Tasks
   alias Pinchflat.Sources
   alias Pinchflat.Sources.Source
@@ -39,6 +38,9 @@ defmodule Pinchflat.SlowIndexing.SlowIndexingHelpers do
   item belonging to the source. You can't tell me the method name isn't descriptive!
   Returns a list of media items or changesets (if the media item couldn't be created).
 
+  For each new media item, the method will also run a user script with the `media_indexed`
+  event, if the script is present.
+
   Indexing is slow and usually returns a list of all media data at once for record creation.
   To help with this, we use a file follower to watch the file that yt-dlp writes to
   so we can create media items as they come in. This parallelizes the process and adds
@@ -64,15 +66,16 @@ defmodule Pinchflat.SlowIndexing.SlowIndexingHelpers do
     source = Repo.reload!(source)
 
     result =
-      Enum.map(media_attributes, fn media_attrs ->
-        case Media.create_media_item_from_backend_attrs(source, media_attrs) do
+      Enum.map(media_attributes, fn media_attrs_struct ->
+        case DownloadingHelpers.create_media_item_and_run_script(source, media_attrs_struct) do
           {:ok, media_item} -> media_item
           {:error, changeset} -> changeset
         end
       end)
 
     Sources.update_source(source, %{last_indexed_at: DateTime.utc_now()})
-    DownloadingHelpers.enqueue_pending_download_tasks(source)
+    # Wait 5s before enqueuing downloads to give the post-indexing user script a chance to run
+    DownloadingHelpers.enqueue_pending_download_tasks(source, kickoff_delay: 5)
 
     result
   end
@@ -118,14 +121,15 @@ defmodule Pinchflat.SlowIndexing.SlowIndexingHelpers do
     end)
   end
 
-  defp create_media_item_and_enqueue_download(source, media_attrs) do
+  defp create_media_item_and_enqueue_download(source, media_attrs_struct) do
     # Reload because the source may have been updated during the (long-running) indexing process
     # and important settings like `download_media` may have changed.
     source = Repo.reload!(source)
 
-    case Media.create_media_item_from_backend_attrs(source, media_attrs) do
+    case DownloadingHelpers.create_media_item_and_run_script(source, media_attrs_struct) do
       {:ok, %MediaItem{} = media_item} ->
-        DownloadingHelpers.kickoff_download_if_pending(media_item)
+        # Wait 5s before enqueuing downloads to give the post-indexing user script a chance to run
+        DownloadingHelpers.kickoff_download_if_pending(media_item, kickoff_delay: 5)
 
       {:error, changeset} ->
         changeset

lib/pinchflat/utils/number_utils.ex

@@ -13,4 +13,27 @@ defmodule Pinchflat.Utils.NumberUtils do
     |> max(minimum)
     |> min(maximum)
   end
+
+  @doc """
+  Converts a number to a human readable byte size. Can take a precision
+  option to specify the number of decimal places to round to.
+
+  Returns {integer(), String.t()}
+  """
+  def human_byte_size(number, opts \\ [])
+  def human_byte_size(nil, opts), do: human_byte_size(0, opts)
+
+  def human_byte_size(number, opts) do
+    precision = Keyword.get(opts, :precision, 2)
+    suffixes = ["B", "KB", "MB", "GB", "TB", "PB", "EB", "ZB", "YB"]
+    base = 1024
+
+    Enum.reduce_while(suffixes, {number / 1.0, "B"}, fn suffix, {value, _} ->
+      if value < base do
+        {:halt, {Float.round(value, precision), suffix}}
+      else
+        {:cont, {value / base, suffix}}
+      end
+    end)
+  end
 end

lib/pinchflat_web/controllers/media_items/media_item_controller.ex

@@ -85,6 +85,7 @@ defmodule PinchflatWeb.MediaItems.MediaItemController do
           |> put_resp_header("accept-ranges", "bytes")
           |> put_resp_header("content-range", "bytes #{start_pos}-#{end_pos}/#{file_size}")
           |> put_resp_header("content-length", to_string(length))
+          |> put_resp_header("content-disposition", "inline; filename=\"#{media_item.title}\"")
           |> send_file(206, media_item.media_filepath, start_pos, length)
 
         {:error, :invalid_range} ->
@@ -92,8 +93,10 @@ defmodule PinchflatWeb.MediaItems.MediaItemController do
 
           conn
           |> put_resp_content_type(mime_type)
-          |> put_resp_header("content-length", to_string(file_size))
           |> put_resp_header("accept-ranges", "bytes")
+          |> put_resp_header("content-range", "bytes 0-#{file_size - 1}/#{file_size}")
+          |> put_resp_header("content-length", to_string(file_size))
+          |> put_resp_header("content-disposition", "inline; filename=\"#{media_item.title}\"")
           |> send_file(200, media_item.media_filepath)
       end
     else

lib/pinchflat_web/controllers/media_items/media_item_html/show.html.heex

@@ -32,8 +32,16 @@
               </div>
               <aside class="mt-4 xl:mt-0">
                 <div>Uploaded: <%= @media_item.upload_date %></div>
-                <div :if={URI.parse(@media_item.original_url).scheme =~ "http"}>
-                  <.subtle_link href={@media_item.original_url} target="_blank">Open Original</.subtle_link>
+                <div>
+                  <span :if={URI.parse(@media_item.original_url).scheme =~ "http"}>
+                    <.subtle_link href={@media_item.original_url} target="_blank">Open Original</.subtle_link>
+                    <span class="mx-2">or</span>
+                  </span>
+                  <span>
+                    <.subtle_link href={~p"/media/#{@media_item.uuid}/stream"} target="_blank">
+                      Open Local Stream
+                    </.subtle_link>
+                  </span>
                 </div>
                 <div class="mt-4 text-bodydark">
                   <.break_on_newline text={@media_item.description} />

lib/pinchflat_web/controllers/media_profiles/media_profile_html/media_profile_form.html.heex

@@ -183,7 +183,7 @@
         options={friendly_format_type_options()}
         type="select"
         label="Include Livestreams"
-        help="Excludes media that comes from a past livestream"
+        help="How to handle past livestreams"
         x-init="$watch('selectedPreset', p => p && ($el.value = presets[p]))"
       />
     </section>

lib/pinchflat_web/controllers/pages/page_controller.ex

@@ -20,14 +20,14 @@ defmodule PinchflatWeb.Pages.PageController do
   end
 
   defp render_home_page(conn) do
+    downloaded_media_items = where(MediaQuery.new(), ^MediaQuery.downloaded())
+
     conn
     |> render(:home,
       media_profile_count: Repo.aggregate(MediaProfile, :count, :id),
       source_count: Repo.aggregate(Source, :count, :id),
-      media_item_count:
-        MediaQuery.new()
-        |> where(^MediaQuery.downloaded())
-        |> Repo.aggregate(:count, :id)
+      media_item_size: Repo.aggregate(downloaded_media_items, :sum, :media_size_bytes),
+      media_item_count: Repo.aggregate(downloaded_media_items, :count, :id)
     )
   end
 

lib/pinchflat_web/controllers/pages/page_html.ex

@@ -1,5 +1,13 @@
 defmodule PinchflatWeb.Pages.PageHTML do
   use PinchflatWeb, :html
 
+  alias Pinchflat.Utils.NumberUtils
+
   embed_templates "page_html/*"
+
+  def readable_media_filesize(media_filesize) do
+    {num, suffix} = NumberUtils.human_byte_size(media_filesize, precision: 1)
+
+    "#{Float.round(num)} #{suffix}"
+  end
 end

lib/pinchflat_web/controllers/pages/page_html/home.html.heex

@@ -1,4 +1,4 @@
-<div class="grid grid-cols-1 gap-4 md:grid-cols-3">
+<div class="grid grid-cols-1 gap-4 md:grid-cols-4">
   <div class="rounded-sm border px-7.5 py-6 shadow-default border-strokedark bg-boxdark">
     <a href={~p"/media_profiles"} class="mt-4 flex flex-col items-center justify-center">
       <span class="text-md font-medium">Media Profile(s)</span>
@@ -23,6 +23,14 @@
       </h4>
     </span>
   </div>
+  <div class="rounded-sm border px-7.5 py-6 shadow-default border-strokedark bg-boxdark">
+    <span class="mt-4 flex flex-col items-center justify-center">
+      <span class="text-md font-medium">Library Size</span>
+      <h4 class="text-title-md font-bold text-white">
+        <%= readable_media_filesize(@media_item_size) %>
+      </h4>
+    </span>
+  </div>
 </div>
 
 <div class="rounded-sm border shadow-default border-strokedark bg-boxdark mt-4 p-5">

lib/pinchflat_web/controllers/sources/source_html/media_item_table_live.ex

@@ -49,6 +49,9 @@ defmodule Pinchflat.Sources.MediaItemTableLive do
             <%= StringUtils.truncate(media_item.title, 50) %>
           </.subtle_link>
         </:col>
+        <:col :let={media_item} label="Upload Date">
+          <%= media_item.upload_date %>
+        </:col>
         <:col :let={media_item} :if={@media_state == "other"} label="Manually Ignored?">
           <.icon name={if media_item.prevent_download, do: "hero-check", else: "hero-x-mark"} />
         </:col>
@@ -147,14 +150,14 @@ defmodule Pinchflat.Sources.MediaItemTableLive do
     |> MediaQuery.require_assoc(:media_profile)
     |> MediaQuery.require_assoc(:media_items_search_index)
     |> where(^dynamic(^MediaQuery.for_source(source) and ^MediaQuery.pending()))
-    |> order_by(desc: fragment("rank"), desc: :id)
+    |> order_by(desc: fragment("rank"), desc: :upload_date)
   end
 
   defp generate_base_query(source, "downloaded") do
     MediaQuery.new()
     |> MediaQuery.require_assoc(:media_items_search_index)
     |> where(^dynamic(^MediaQuery.for_source(source) and ^MediaQuery.downloaded()))
-    |> order_by(desc: fragment("rank"), desc: :id)
+    |> order_by(desc: fragment("rank"), desc: :upload_date)
   end
 
   defp generate_base_query(source, "other") do
@@ -167,7 +170,7 @@ defmodule Pinchflat.Sources.MediaItemTableLive do
           (not (^MediaQuery.downloaded()) and not (^MediaQuery.pending()))
       )
     )
-    |> order_by(desc: fragment("rank"), desc: :id)
+    |> order_by(desc: fragment("rank"), desc: :upload_date)
   end
 
   defp filter_base_query(base_query, search_term) do

lib/pinchflat_web/router.ex

@@ -10,7 +10,7 @@ defmodule PinchflatWeb.Router do
     plug :fetch_session
     plug :fetch_live_flash
     plug :put_root_layout, html: {PinchflatWeb.Layouts, :root}
-    plug :protect_from_forgery
+    plug :protect_from_forgery, with: :clear_session
     plug :put_secure_browser_headers
     plug :allow_iframe_embed
   end

test/pinchflat/downloading/downloading_helpers_test.exs

@@ -6,9 +6,13 @@ defmodule Pinchflat.Downloading.DownloadingHelpersTest do
   import Pinchflat.ProfilesFixtures
 
   alias Pinchflat.Tasks
+  alias Pinchflat.Media.MediaItem
+  alias Pinchflat.Utils.FilesystemUtils
   alias Pinchflat.Downloading.DownloadingHelpers
   alias Pinchflat.Downloading.MediaDownloadWorker
 
+  alias Pinchflat.YtDlp.Media, as: YtDlpMedia
+
   describe "enqueue_pending_download_tasks/1" do
     test "it enqueues a job for each pending media item" do
       source = source_fixture()
@@ -19,6 +23,16 @@ defmodule Pinchflat.Downloading.DownloadingHelpersTest do
       assert_enqueued(worker: MediaDownloadWorker, args: %{"id" => media_item.id})
     end
 
+    test "it can optionally delay when those jobs are enqueued" do
+      source = source_fixture()
+      _media_item = media_item_fixture(source_id: source.id, media_filepath: nil)
+
+      assert :ok = DownloadingHelpers.enqueue_pending_download_tasks(source, kickoff_delay: 60)
+      [job] = all_enqueued(worker: MediaDownloadWorker)
+
+      assert_in_delta DateTime.diff(job.scheduled_at, now()), 60, 1
+    end
+
     test "it does not enqueue a job for media items with a filepath" do
       source = source_fixture()
       _media_item = media_item_fixture(source_id: source.id, media_filepath: "some/filepath.mp4")
@@ -84,6 +98,13 @@ defmodule Pinchflat.Downloading.DownloadingHelpersTest do
       assert_enqueued(worker: MediaDownloadWorker, args: %{"id" => media_item.id})
     end
 
+    test "it can optionally delay when those jobs are enqueued", %{media_item: media_item} do
+      assert {:ok, _} = DownloadingHelpers.kickoff_download_if_pending(media_item, kickoff_delay: 60)
+      [job] = all_enqueued(worker: MediaDownloadWorker)
+
+      assert_in_delta DateTime.diff(job.scheduled_at, now()), 60, 1
+    end
+
     test "creates and returns a download task record", %{media_item: media_item} do
       assert {:ok, task} = DownloadingHelpers.kickoff_download_if_pending(media_item)
 
@@ -138,4 +159,67 @@ defmodule Pinchflat.Downloading.DownloadingHelpersTest do
       refute_enqueued(worker: MediaDownloadWorker)
     end
   end
+
+  describe "create_media_item_and_run_script/2" do
+    setup do
+      FilesystemUtils.write_p!(filepath(), "")
+      File.chmod(filepath(), 0o755)
+
+      on_exit(fn -> File.rm(filepath()) end)
+
+      source = source_fixture()
+
+      media_attrs =
+        media_attributes_return_fixture()
+        |> Phoenix.json_library().decode!()
+        |> YtDlpMedia.response_to_struct()
+
+      {:ok, source: source, media_attrs: media_attrs}
+    end
+
+    test "creates a media item for a given source and attributes", %{source: source, media_attrs: media_attrs} do
+      assert {:ok, %MediaItem{} = media_item} = DownloadingHelpers.create_media_item_and_run_script(source, media_attrs)
+
+      assert media_item.source_id == source.id
+      assert media_item.title == media_attrs.title
+      assert media_item.media_id == media_attrs.media_id
+      assert media_item.original_url == media_attrs.original_url
+      assert media_item.description == media_attrs.description
+    end
+
+    test "returns an error if the media item cannot be created", %{source: source, media_attrs: media_attrs} do
+      media_attrs = %YtDlpMedia{media_attrs | media_id: nil}
+
+      assert {:error, %Ecto.Changeset{}} = DownloadingHelpers.create_media_item_and_run_script(source, media_attrs)
+    end
+
+    test "runs a script if the media item is created", %{source: source, media_attrs: media_attrs} do
+      # We *love* indirectly testing side effects
+      tmp_dir = Application.get_env(:pinchflat, :tmpfile_directory)
+      filename = "#{tmp_dir}/test_file-#{Enum.random(1..1000)}"
+      File.write(filepath(), "#!/bin/bash\ntouch #{filename}\n")
+
+      refute File.exists?(filename)
+      assert {:ok, %MediaItem{}} = DownloadingHelpers.create_media_item_and_run_script(source, media_attrs)
+      assert File.exists?(filename)
+    end
+
+    test "does not run a script if the media item already exists", %{source: source, media_attrs: media_attrs} do
+      {:ok, %MediaItem{}} = DownloadingHelpers.create_media_item_and_run_script(source, media_attrs)
+
+      tmp_dir = Application.get_env(:pinchflat, :tmpfile_directory)
+      filename = "#{tmp_dir}/test_file-#{Enum.random(1..1000)}"
+      File.write(filepath(), "#!/bin/bash\ntouch #{filename}\n")
+
+      refute File.exists?(filename)
+      assert {:ok, %MediaItem{}} = DownloadingHelpers.create_media_item_and_run_script(source, media_attrs)
+      refute File.exists?(filename)
+    end
+
+    defp filepath do
+      base_dir = Application.get_env(:pinchflat, :extras_directory)
+
+      Path.join([base_dir, "user-scripts", "lifecycle"])
+    end
+  end
 end

test/pinchflat/fast_indexing/fast_indexing_helpers_test.exs

@@ -28,6 +28,16 @@ defmodule Pinchflat.FastIndexing.FastIndexingHelpersTest do
       assert worker.args["id"] == media_item.id
     end
 
+    test "enqueues the worker with a small delay", %{source: source} do
+      expect(HTTPClientMock, :get, fn _url -> {:ok, "<yt:videoId>test_1</yt:videoId>"} end)
+
+      FastIndexingHelpers.kickoff_download_tasks_from_youtube_rss_feed(source)
+
+      [job | _] = all_enqueued(worker: MediaDownloadWorker)
+
+      assert_in_delta DateTime.diff(job.scheduled_at, now()), 5, 1
+    end
+
     test "does not enqueue a new worker for the source's media IDs we already know about", %{source: source} do
       expect(HTTPClientMock, :get, fn _url -> {:ok, "<yt:videoId>test_1</yt:videoId>"} end)
       media_item_fixture(source_id: source.id, media_id: "test_1")

test/pinchflat/media_test.exs

@@ -835,6 +835,18 @@ defmodule Pinchflat.MediaTest do
       assert media_item_1.id == media_item_2.id
       assert media_item_2.title == different_attrs.title
     end
+
+    test "returns an error if the media item cannot be created" do
+      source = source_fixture()
+
+      media_attrs =
+        media_attributes_return_fixture()
+        |> Phoenix.json_library().decode!()
+        |> Map.put("id", nil)
+        |> YtDlpMedia.response_to_struct()
+
+      assert {:error, %Ecto.Changeset{}} = Media.create_media_item_from_backend_attrs(source, media_attrs)
+    end
   end
 
   describe "update_media_item/2" do

test/pinchflat/slow_indexing/slow_indexing_helpers_test.exs

@@ -158,6 +158,16 @@ defmodule Pinchflat.SlowIndexing.SlowIndexingHelpersTest do
       assert_enqueued(worker: MediaDownloadWorker, args: %{"id" => media_item.id})
     end
 
+    test "it enqueues the job with a small delay", %{source: source} do
+      media_item = media_item_fixture(source_id: source.id, media_filepath: nil)
+
+      SlowIndexingHelpers.index_and_enqueue_download_for_media_items(source)
+
+      [job] = all_enqueued(worker: MediaDownloadWorker, args: %{"id" => media_item.id})
+
+      assert_in_delta DateTime.diff(job.scheduled_at, now()), 5, 1
+    end
+
     test "it does not attach tasks if the source is set to not download" do
       source = source_fixture(download_media: false)
       media_item = media_item_fixture(source_id: source.id, media_filepath: nil)
@@ -235,6 +245,26 @@ defmodule Pinchflat.SlowIndexing.SlowIndexingHelpersTest do
       assert_enqueued(worker: MediaDownloadWorker)
     end
 
+    test "sets a small delay on the download job", %{source: source} do
+      watcher_poll_interval = Application.get_env(:pinchflat, :file_watcher_poll_interval)
+
+      stub(YtDlpRunnerMock, :run, fn _url, _opts, _ot, addl_opts ->
+        filepath = Keyword.get(addl_opts, :output_filepath)
+        File.write(filepath, source_attributes_return_fixture())
+
+        # Need to add a delay to ensure the file watcher has time to read the file
+        :timer.sleep(watcher_poll_interval * 2)
+        # We know we're testing the file watcher since the syncronous call will only
+        # return an empty string (creating no records)
+        {:ok, ""}
+      end)
+
+      SlowIndexingHelpers.index_and_enqueue_download_for_media_items(source)
+      [job | _] = all_enqueued(worker: MediaDownloadWorker)
+
+      assert_in_delta DateTime.diff(job.scheduled_at, now()), 5, 1
+    end
+
     test "does not enqueue downloads if the source is set to not download" do
       watcher_poll_interval = Application.get_env(:pinchflat, :file_watcher_poll_interval)
       source = source_fixture(download_media: false)

test/pinchflat/utils/number_utils_test.exs

@@ -16,4 +16,35 @@ defmodule Pinchflat.Utils.NumberUtilsTest do
       assert NumberUtils.clamp(2, 1, 3) == 2
     end
   end
+
+  describe "human_byte_size/1" do
+    test "converts byte size to human readable format" do
+      assert NumberUtils.human_byte_size(1024) == {1, "KB"}
+      assert NumberUtils.human_byte_size(1024 * 1024) == {1, "MB"}
+      assert NumberUtils.human_byte_size(1024 * 1024 * 1024) == {1, "GB"}
+      assert NumberUtils.human_byte_size(1024 * 1024 * 1024 * 1024) == {1, "TB"}
+      assert NumberUtils.human_byte_size(1024 * 1024 * 1024 * 1024 * 1024) == {1, "PB"}
+      assert NumberUtils.human_byte_size(1024 * 1024 * 1024 * 1024 * 1024 * 1024) == {1, "EB"}
+      assert NumberUtils.human_byte_size(1024 * 1024 * 1024 * 1024 * 1024 * 1024 * 1024) == {1, "ZB"}
+      assert NumberUtils.human_byte_size(1024 * 1024 * 1024 * 1024 * 1024 * 1024 * 1024 * 1024) == {1, "YB"}
+    end
+
+    test "returns the number when it is less than 1024" do
+      assert NumberUtils.human_byte_size(512) == {512, "B"}
+    end
+
+    test "optionally takes a precision" do
+      assert NumberUtils.human_byte_size(1234 * 1024, precision: 0) == {1, "MB"}
+      assert NumberUtils.human_byte_size(1234 * 1024, precision: 1) == {1.2, "MB"}
+      assert NumberUtils.human_byte_size(1234 * 1024, precision: 2) == {1.21, "MB"}
+    end
+
+    test "handles 0's well" do
+      assert NumberUtils.human_byte_size(0) == {0, "B"}
+    end
+
+    test "handles nil well" do
+      assert NumberUtils.human_byte_size(nil) == {0, "B"}
+    end
+  end
 end

test/pinchflat_web/controllers/media_item_controller_test.exs

@@ -166,6 +166,7 @@ defmodule PinchflatWeb.MediaItemControllerTest do
       assert conn.status == 206
       assert {"content-range", "bytes 0-100/#{filesize}"} in conn.resp_headers
       assert {"content-length", "101"} in conn.resp_headers
+      assert {"content-disposition", "inline; filename=\"#{media_item.title}\""} in conn.resp_headers
     end
 
     test "streams the specified range", %{conn: conn, media_item: media_item} do
@@ -241,6 +242,8 @@ defmodule PinchflatWeb.MediaItemControllerTest do
 
       assert conn.status == 200
       assert {"content-length", to_string(filesize)} in conn.resp_headers
+      assert {"content-range", "bytes 0-#{filesize - 1}/#{filesize}"} in conn.resp_headers
+      assert {"content-disposition", "inline; filename=\"#{media_item.title}\""} in conn.resp_headers
     end
 
     test "streams the entire file", %{conn: conn, media_item: media_item} do