Source NFO downloads (#95)

* Hooked up series directory finding to source metadata runner

* Fixed aired NFO tag for episodes

* Updated MI NFO builder to take in a filepath

* Hooked up NFO generation to the source worker

* Added NFO controls to form

* Improved the way the source metadata worker updates the source

* Consolidated NFO selection options in media profile instead of source

lib/pinchflat/downloading/download_option_builder.ex

@@ -3,6 +3,7 @@ defmodule Pinchflat.Downloading.DownloadOptionBuilder do
   Builds the options for yt-dlp to download media based on the given media profile.
   """
 
+  alias Pinchflat.Sources.Source
   alias Pinchflat.Media.MediaItem
   alias Pinchflat.Downloading.OutputPathBuilder
 
@@ -26,6 +27,18 @@ defmodule Pinchflat.Downloading.DownloadOptionBuilder do
     {:ok, built_options}
   end
 
+  @doc """
+  Builds the output path for yt-dlp to download media based on the given source's
+  media profile.
+
+  Returns binary()
+  """
+  def build_output_path_for(%Source{} = source_with_preloads) do
+    output_path_template = source_with_preloads.media_profile.output_path_template
+
+    build_output_path(output_path_template, source_with_preloads)
+  end
+
   defp default_options do
     [:no_progress, :windows_filenames]
   end
@@ -104,23 +117,19 @@ defmodule Pinchflat.Downloading.DownloadOptionBuilder do
   end
 
   defp output_options(media_item_with_preloads) do
-    output_path_template = media_item_with_preloads.source.media_profile.output_path_template
-
     [
-      output: build_output_path(output_path_template, media_item_with_preloads)
+      output: build_output_path_for(media_item_with_preloads.source)
     ]
   end
 
-  defp build_output_path(string, media_item_with_preloads) do
-    additional_options_map = output_options_map(media_item_with_preloads)
+  defp build_output_path(string, source) do
+    additional_options_map = output_options_map(source)
     {:ok, output_path} = OutputPathBuilder.build(string, additional_options_map)
 
     Path.join(base_directory(), output_path)
   end
 
-  defp output_options_map(media_item_with_preloads) do
-    source = media_item_with_preloads.source
-
+  defp output_options_map(source) do
     %{
       "source_custom_name" => source.custom_name,
       "source_collection_type" => source.collection_type
@@ -137,7 +146,7 @@ defmodule Pinchflat.Downloading.DownloadOptionBuilder do
     |> String.split(~r{\.}, include_captures: true)
     |> List.insert_at(-3, "-thumb")
     |> Enum.join()
-    |> build_output_path(media_item_with_preloads)
+    |> build_output_path(media_item_with_preloads.source)
   end
 
   defp base_directory do

lib/pinchflat/downloading/media_downloader.ex

@@ -56,7 +56,9 @@ defmodule Pinchflat.Downloading.MediaDownloader do
 
   defp determine_nfo_filepath(media_item, parsed_json) do
     if media_item.source.media_profile.download_nfo do
-      NfoBuilder.build_and_store_for_media_item(parsed_json)
+      filepath = Path.rootname(parsed_json["filepath"]) <> ".nfo"
+
+      NfoBuilder.build_and_store_for_media_item(filepath, parsed_json)
     else
       nil
     end

lib/pinchflat/metadata/metadata_file_helpers.ex

@@ -63,6 +63,43 @@ defmodule Pinchflat.Metadata.MetadataFileHelpers do
     Date.from_iso8601!("#{year}-#{month}-#{day}")
   end
 
+  @doc """
+  Attempts to determine the series directory from a media filepath.
+  The series directory is the "root" directory for a given source
+  which should contain all the season-level folders of that source.
+
+  Used for determining where to store things like NFO data and banners
+  for media center apps. Not useful without a media center app.
+
+  Returns {:ok, binary()} | {:error, :indeterminable}
+  """
+  def series_directory_from_media_filepath(media_filepath) do
+    # Matches "s" or "season" (case-insensitive)
+    # followed by an optional non-word character (. or _ or <space>, etc)
+    # followed by at least one digit
+    # followed immediately by the end of the string
+    # Example matches: s1, s.1, s01 season 1, Season.01, Season_1, Season 1, Season1
+    # Example non-matches: s01e01, season, series 1,
+    season_regex = ~r/^s(eason)?(\W|_)?\d{1,}$/i
+
+    {series_directory, found_series_directory} =
+      media_filepath
+      |> Path.split()
+      |> Enum.reduce_while({[], false}, fn part, {directory_acc, _} ->
+        if String.match?(part, season_regex) do
+          {:halt, {directory_acc, true}}
+        else
+          {:cont, {directory_acc ++ [part], false}}
+        end
+      end)
+
+    if found_series_directory do
+      {:ok, Path.join(series_directory)}
+    else
+      {:error, :indeterminable}
+    end
+  end
+
   defp fetch_thumbnail_from_url(url) do
     http_client = Application.get_env(:pinchflat, :http_client, Pinchflat.HTTP.HTTPClient)
     {:ok, body} = http_client.get(url, [], body_format: :binary)

lib/pinchflat/metadata/nfo_builder.ex

@@ -9,13 +9,11 @@ defmodule Pinchflat.Metadata.NfoBuilder do
 
   @doc """
   Builds an NFO file for a media item (read: single "episode") and
-  stores it in the same directory as the media file. Has the same name
-  as the media file, but with a .nfo extension.
+  stores it at the specified location.
 
   Returns the filepath of the NFO file.
   """
-  def build_and_store_for_media_item(metadata) do
-    filepath = Path.rootname(metadata["filepath"]) <> ".nfo"
+  def build_and_store_for_media_item(filepath, metadata) do
     nfo = build_for_media_item(metadata)
 
     FilesystemHelpers.write_p!(filepath, nfo)
@@ -23,6 +21,20 @@ defmodule Pinchflat.Metadata.NfoBuilder do
     filepath
   end
 
+  @doc """
+  Builds an NFO file for a souce and stores it at the specified location.
+  Technically works for playlists, but it's really made for channels.
+
+  Returns the filepath of the NFO file.
+  """
+  def build_and_store_for_source(filepath, metadata) do
+    nfo = build_for_source(metadata)
+
+    FilesystemHelpers.write_p!(filepath, nfo)
+
+    filepath
+  end
+
   defp build_for_media_item(metadata) do
     upload_date = MetadataFileHelpers.parse_upload_date(metadata["upload_date"])
     # Cribbed from a combination of the Kodi wiki, ytdl-nfo, and ytdl-sub.
@@ -34,11 +46,23 @@ defmodule Pinchflat.Metadata.NfoBuilder do
       <showtitle>#{metadata["uploader"]}</showtitle>
       <uniqueid type="youtube" default="true">#{metadata["id"]}</uniqueid>
       <plot>#{metadata["description"]}</plot>
-      <premiered>#{upload_date}</premiered>
+      <aired>#{upload_date}</aired>
       <season>#{upload_date.year}</season>
       <episode>#{Calendar.strftime(upload_date, "%m%d")}</episode>
       <genre>YouTube</genre>
     </episodedetails>
     """
   end
+
+  defp build_for_source(metadata) do
+    """
+    <?xml version="1.0" encoding="UTF-8" standalone="yes" ?>
+    <tvshow>
+      <title>#{metadata["title"]}</title>
+      <plot>#{metadata["description"]}</plot>
+      <uniqueid type="youtube" default="true">#{metadata["id"]}</uniqueid>
+      <genre>YouTube</genre>
+    </tvshow>
+    """
+  end
 end

lib/pinchflat/metadata/source_metadata_storage_worker.ex

@@ -4,10 +4,7 @@ defmodule Pinchflat.Metadata.SourceMetadataStorageWorker do
   use Oban.Worker,
     queue: :remote_metadata,
     tags: ["media_source", "source_metadata", "remote_metadata"],
-    max_attempts: 1,
-    # This is the only thing stopping this job from calling itself
-    # in an infinite loop.
-    unique: [period: 600]
+    max_attempts: 3
 
   require Logger
 
@@ -15,8 +12,10 @@ defmodule Pinchflat.Metadata.SourceMetadataStorageWorker do
   alias Pinchflat.Repo
   alias Pinchflat.Tasks
   alias Pinchflat.Sources
+  alias Pinchflat.Metadata.NfoBuilder
   alias Pinchflat.YtDlp.MediaCollection
   alias Pinchflat.Metadata.MetadataFileHelpers
+  alias Pinchflat.Downloading.DownloadOptionBuilder
 
   @doc """
   Starts the source metadata storage worker and creates a task for the source.
@@ -30,27 +29,67 @@ defmodule Pinchflat.Metadata.SourceMetadataStorageWorker do
   end
 
   @doc """
-  Fetches and stores metadata for a source in the secret metadata location.
+  Fetches and stores various forms of metadata for a source:
+    - JSON metadata for internal use
+    - The series directory for the source
+    - The NFO file for the source (if specified)
+
+  The worker is kicked off after a source is inserted/updated - this can
+  take an unknown amount of time so don't rely on this data being here
+  before, say, the first indexing or downloading task is complete.
 
   Returns :ok
   """
   @impl Oban.Worker
   def perform(%Oban.Job{args: %{"id" => source_id}}) do
-    source = Repo.preload(Sources.get_source!(source_id), :metadata)
-    {:ok, metadata} = MediaCollection.get_source_metadata(source.original_url)
+    source = Repo.preload(Sources.get_source!(source_id), [:metadata, :media_profile])
+    source_metadata = fetch_source_metadata(source)
+    series_directory = determine_series_directory(source)
 
-    # Since updating a source kicks this job off again, we enforce job uniqueness (above)
-    # to once, per source, per x minutes. This is to prevent a job from calling itself
-    # in an infinite loop.
-    Sources.update_source(source, %{
-      metadata: %{
-        metadata_filepath: MetadataFileHelpers.compress_and_store_metadata_for(source, metadata)
-      }
-    })
+    # `run_post_commit_tasks: false` prevents this from running in an infinite loop
+    Sources.update_source(
+      source,
+      %{
+        series_directory: series_directory,
+        nfo_filepath: store_source_nfo(source, series_directory, source_metadata),
+        metadata: %{
+          metadata_filepath: store_source_metadata(source, source_metadata)
+        }
+      },
+      run_post_commit_tasks: false
+    )
 
     :ok
   rescue
     Ecto.NoResultsError -> Logger.info("#{__MODULE__} discarded: source #{source_id} not found")
     Ecto.StaleEntryError -> Logger.info("#{__MODULE__} discarded: source #{source_id} stale")
   end
+
+  defp fetch_source_metadata(source) do
+    {:ok, metadata} = MediaCollection.get_source_metadata(source.original_url)
+
+    metadata
+  end
+
+  defp store_source_metadata(source, metadata) do
+    MetadataFileHelpers.compress_and_store_metadata_for(source, metadata)
+  end
+
+  defp determine_series_directory(source) do
+    output_path = DownloadOptionBuilder.build_output_path_for(source)
+    {:ok, %{filepath: filepath}} = MediaCollection.get_source_details(source.original_url, output: output_path)
+
+    case MetadataFileHelpers.series_directory_from_media_filepath(filepath) do
+      {:ok, series_directory} -> series_directory
+      {:error, _} -> nil
+    end
+  end
+
+  defp store_source_nfo(source, series_directory, metadata) do
+    if source.media_profile.download_nfo && series_directory do
+      nfo_filepath = Path.join(series_directory, "tvshow.nfo")
+
+      NfoBuilder.build_and_store_for_source(nfo_filepath, metadata)
+    end
+  end
 end

lib/pinchflat/sources/source.ex

@@ -17,6 +17,8 @@ defmodule Pinchflat.Sources.Source do
     collection_id
     collection_type
     custom_name
+    nfo_filepath
+    series_directory
     index_frequency_minutes
     fast_index
     download_media
@@ -52,6 +54,8 @@ defmodule Pinchflat.Sources.Source do
     field :collection_name, :string
     field :collection_id, :string
     field :collection_type, Ecto.Enum, values: [:channel, :playlist]
+    field :nfo_filepath, :string
+    field :series_directory, :string
     field :index_frequency_minutes, :integer, default: 60 * 24
     field :fast_index, :boolean, default: false
     field :download_media, :boolean, default: true
@@ -99,4 +103,9 @@ defmodule Pinchflat.Sources.Source do
     # minutes
     15
   end
+
+  @doc false
+  def filepath_attributes do
+    ~w(nfo_filepath)a
+  end
 end

lib/pinchflat/sources/sources.ex

@@ -51,15 +51,19 @@ defmodule Pinchflat.Sources do
   though we know it's going to fail so it picks up any addl. database errors
   and fulfills our return contract.
 
+  You can pass options to control the behavior of the function:
+    - `run_post_commit_tasks` (default: true) - If false, the function will not
+      enqueue any tasks in `commit_and_handle_tasks`.
+
   Returns {:ok, %Source{}} | {:error, %Ecto.Changeset{}}
   """
-  def create_source(attrs) do
+  def create_source(attrs, opts \\ []) do
     case change_source(%Source{}, attrs, :initial) do
       %Ecto.Changeset{valid?: true} ->
         %Source{}
         |> maybe_change_source_from_url(attrs)
         |> maybe_change_indexing_frequency()
-        |> commit_and_handle_tasks()
+        |> commit_and_handle_tasks(opts)
 
       changeset ->
         Repo.insert(changeset)
@@ -79,15 +83,19 @@ defmodule Pinchflat.Sources do
   though we know it's going to fail so it picks up any addl. database errors
   and fulfills our return contract.
 
+  You can pass options to control the behavior of the function:
+    - `run_post_commit_tasks` (default: true) - If false, the function will not
+      enqueue any tasks in `commit_and_handle_tasks`.
+
   Returns {:ok, %Source{}} | {:error, %Ecto.Changeset{}}
   """
-  def update_source(%Source{} = source, attrs) do
+  def update_source(%Source{} = source, attrs, opts \\ []) do
     case change_source(source, attrs, :initial) do
       %Ecto.Changeset{valid?: true} ->
         source
         |> maybe_change_source_from_url(attrs)
         |> maybe_change_indexing_frequency()
-        |> commit_and_handle_tasks()
+        |> commit_and_handle_tasks(opts)
 
       changeset ->
         Repo.update(changeset)
@@ -102,7 +110,6 @@ defmodule Pinchflat.Sources do
   """
   def delete_source(%Source{} = source, opts \\ []) do
     delete_files = Keyword.get(opts, :delete_files, false)
-
     Tasks.delete_tasks_for(source)
 
     source
@@ -111,7 +118,11 @@ defmodule Pinchflat.Sources do
       Media.delete_media_item(media_item, delete_files: delete_files)
     end)
 
-    delete_source_metadata_files(source)
+    if delete_files do
+      delete_source_files(source)
+    end
+
+    delete_internal_metadata_files(source)
     Repo.delete(source)
   end
 
@@ -134,22 +145,27 @@ defmodule Pinchflat.Sources do
     end
   end
 
-  defp delete_source_metadata_files(source) do
+  defp delete_source_files(source) do
+    mapped_struct = Map.from_struct(source)
+
+    Source.filepath_attributes()
+    |> Enum.map(fn field -> mapped_struct[field] end)
+    |> Enum.filter(&is_binary/1)
+    |> Enum.each(&FilesystemHelpers.delete_file_and_remove_empty_directories/1)
+  end
+
+  defp delete_internal_metadata_files(source) do
     metadata = Repo.preload(source, :metadata).metadata || %SourceMetadata{}
     mapped_struct = Map.from_struct(metadata)
 
-    filepaths =
-      SourceMetadata.filepath_attributes()
-      |> Enum.map(fn field -> mapped_struct[field] end)
-      |> Enum.filter(&is_binary/1)
-
-    Enum.each(filepaths, &FilesystemHelpers.delete_file_and_remove_empty_directories/1)
+    SourceMetadata.filepath_attributes()
+    |> Enum.map(fn field -> mapped_struct[field] end)
+    |> Enum.filter(&is_binary/1)
+    |> Enum.each(&FilesystemHelpers.delete_file_and_remove_empty_directories/1)
   end
 
   defp add_source_details_to_changeset(source, changeset) do
-    %Ecto.Changeset{changes: changes} = changeset
-
-    case MediaCollection.get_source_details(changes.original_url) do
+    case MediaCollection.get_source_details(changeset.changes.original_url) do
       {:ok, source_details} ->
         add_source_details_by_collection_type(source, changeset, source_details)
 
@@ -198,12 +214,16 @@ defmodule Pinchflat.Sources do
     end
   end
 
-  defp commit_and_handle_tasks(changeset) do
+  defp commit_and_handle_tasks(changeset, opts) do
+    run_post_commit_tasks = Keyword.get(opts, :run_post_commit_tasks, true)
+
     case Repo.insert_or_update(changeset) do
       {:ok, %Source{} = source} ->
-        maybe_handle_media_tasks(changeset, source)
-        maybe_run_indexing_task(changeset, source)
-        run_metadata_storage_task(source)
+        if run_post_commit_tasks do
+          maybe_handle_media_tasks(changeset, source)
+          maybe_run_indexing_task(changeset, source)
+          run_metadata_storage_task(source)
+        end
 
         {:ok, source}
 

lib/pinchflat/yt_dlp/media_collection.ex

@@ -64,14 +64,14 @@ defmodule Pinchflat.YtDlp.MediaCollection do
 
   Returns {:ok, map()} | {:error, any, ...}.
   """
-  def get_source_details(source_url) do
+  def get_source_details(source_url, addl_opts \\ []) do
     # `ignore_no_formats_error` is necessary because yt-dlp will error out if
     # the first video has not released yet (ie: is a premier). We don't care about
     # available formats since we're just getting the source details
-    opts = [:simulate, :skip_download, :ignore_no_formats_error, playlist_end: 1]
-    output_template = "%(.{channel,channel_id,playlist_id,playlist_title})j"
+    command_opts = [:simulate, :skip_download, :ignore_no_formats_error, playlist_end: 1] ++ addl_opts
+    output_template = "%(.{channel,channel_id,playlist_id,playlist_title,filename})j"
 
-    with {:ok, output} <- backend_runner().run(source_url, opts, output_template),
+    with {:ok, output} <- backend_runner().run(source_url, command_opts, output_template),
          {:ok, parsed_json} <- Phoenix.json_library().decode(output) do
       {:ok, format_source_details(parsed_json)}
     else
@@ -112,7 +112,11 @@ defmodule Pinchflat.YtDlp.MediaCollection do
       channel_id: response["channel_id"],
       channel_name: response["channel"],
       playlist_id: response["playlist_id"],
-      playlist_name: response["playlist_title"]
+      playlist_name: response["playlist_title"],
+      # It's not a name, it's a path dammit!
+      # This actually isn't used for the inital response - it's
+      # used later to update a source's metadata
+      filepath: response["filename"]
     }
   end