Refactor modules into contexts (#78)

* [WIP] break out a few contexts, start refactoring fast index modules

* [WIP] more contexts, this time around slow indexing and downloads

* [WIP] got all tests passing

* [WIP] Added moduledocs

* Built a genserver to rename old jobs on boot

* Added a module naming check; moved things around

* Fixed specs

test/pinchflat/downloading/media_downloader_test.exs

@@ -0,0 +1,106 @@
+defmodule Pinchflat.Downloading.MediaDownloaderTest do
+  use Pinchflat.DataCase
+  import Mox
+  import Pinchflat.MediaFixtures
+
+  alias Pinchflat.Downloading.MediaDownloader
+
+  setup :verify_on_exit!
+
+  setup do
+    media_item =
+      Repo.preload(
+        media_item_fixture(%{title: "Something", media_filepath: nil}),
+        [:metadata, source: :media_profile]
+      )
+
+    stub(HTTPClientMock, :get, fn _url, _headers, _opts ->
+      {:ok, ""}
+    end)
+
+    {:ok, %{media_item: media_item}}
+  end
+
+  describe "download_for_media_item/3" do
+    test "it calls the backend runner", %{media_item: media_item} do
+      expect(YtDlpRunnerMock, :run, fn url, _opts, ot ->
+        assert url == media_item.original_url
+        assert ot == "after_move:%()j"
+
+        {:ok, render_metadata(:media_metadata)}
+      end)
+
+      assert {:ok, _} = MediaDownloader.download_for_media_item(media_item)
+    end
+
+    test "it saves the metadata filepatha to the database", %{media_item: media_item} do
+      expect(YtDlpRunnerMock, :run, fn _url, _opts, _ot ->
+        {:ok, render_metadata(:media_metadata)}
+      end)
+
+      assert is_nil(media_item.metadata)
+      assert {:ok, updated_media_item} = MediaDownloader.download_for_media_item(media_item)
+
+      assert updated_media_item.metadata.metadata_filepath =~ "media_items/#{media_item.id}/metadata.json.gz"
+      assert updated_media_item.metadata.thumbnail_filepath =~ "media_items/#{media_item.id}/maxresdefault.jpg"
+    end
+
+    test "errors are passed through", %{media_item: media_item} do
+      expect(YtDlpRunnerMock, :run, fn _url, _opts, _ot ->
+        {:error, :some_error}
+      end)
+
+      assert {:error, :some_error} = MediaDownloader.download_for_media_item(media_item)
+    end
+  end
+
+  describe "download_for_media_item/3 when testing media_item attributes" do
+    setup do
+      expect(YtDlpRunnerMock, :run, fn _url, _opts, _ot ->
+        {:ok, render_metadata(:media_metadata)}
+      end)
+
+      :ok
+    end
+
+    test "it sets the media_downloaded_at", %{media_item: media_item} do
+      assert media_item.media_downloaded_at == nil
+      assert {:ok, updated_media_item} = MediaDownloader.download_for_media_item(media_item)
+      assert DateTime.diff(DateTime.utc_now(), updated_media_item.media_downloaded_at) < 2
+    end
+
+    test "it extracts the title", %{media_item: media_item} do
+      assert {:ok, updated_media_item} = MediaDownloader.download_for_media_item(media_item)
+      assert updated_media_item.title == "Trying to Wheelie Without the Rear Brake"
+    end
+
+    test "it extracts the description", %{media_item: media_item} do
+      assert {:ok, updated_media_item} = MediaDownloader.download_for_media_item(media_item)
+      assert is_binary(updated_media_item.description)
+    end
+
+    test "it extracts the media_filepath", %{media_item: media_item} do
+      assert media_item.media_filepath == nil
+      assert {:ok, updated_media_item} = MediaDownloader.download_for_media_item(media_item)
+      assert String.ends_with?(updated_media_item.media_filepath, ".mkv")
+    end
+
+    test "it extracts the subtitle_filepaths", %{media_item: media_item} do
+      assert media_item.subtitle_filepaths == []
+      assert {:ok, updated_media_item} = MediaDownloader.download_for_media_item(media_item)
+      assert [["de", _], ["en", _] | _rest] = updated_media_item.subtitle_filepaths
+    end
+
+    test "it extracts the thumbnail_filepath", %{media_item: media_item} do
+      assert media_item.thumbnail_filepath == nil
+      assert {:ok, updated_media_item} = MediaDownloader.download_for_media_item(media_item)
+      assert String.ends_with?(updated_media_item.thumbnail_filepath, ".webp")
+    end
+
+    test "it extracts the metadata_filepath", %{media_item: media_item} do
+      assert media_item.metadata_filepath == nil
+      assert {:ok, updated_media_item} = MediaDownloader.download_for_media_item(media_item)
+      assert String.ends_with?(updated_media_item.metadata_filepath, ".info.json")
+    end
+  end
+end