Refactor modules into contexts (#78)

* [WIP] break out a few contexts, start refactoring fast index modules

* [WIP] more contexts, this time around slow indexing and downloads

* [WIP] got all tests passing

* [WIP] Added moduledocs

* Built a genserver to rename old jobs on boot

* Added a module naming check; moved things around

* Fixed specs

test/pinchflat/downloading/media_download_worker_test.exs

@@ -0,0 +1,85 @@
+defmodule Pinchflat.Downloading.MediaDownloadWorkerTest do
+  use Pinchflat.DataCase
+
+  import Mox
+  import Pinchflat.MediaFixtures
+
+  alias Pinchflat.Sources
+  alias Pinchflat.Downloading.MediaDownloadWorker
+  alias Pinchflat.Filesystem.FilesystemDataWorker
+
+  setup :verify_on_exit!
+
+  setup do
+    media_item =
+      Repo.preload(
+        media_item_fixture(%{media_filepath: nil}),
+        [:metadata, source: :media_profile]
+      )
+
+    stub(HTTPClientMock, :get, fn _url, _headers, _opts ->
+      {:ok, ""}
+    end)
+
+    {:ok, %{media_item: media_item}}
+  end
+
+  describe "perform/1" do
+    test "it saves attributes to the media_item", %{media_item: media_item} do
+      expect(YtDlpRunnerMock, :run, fn _url, _opts, _ot ->
+        {:ok, render_metadata(:media_metadata)}
+      end)
+
+      assert media_item.media_filepath == nil
+      perform_job(MediaDownloadWorker, %{id: media_item.id})
+      assert Repo.reload(media_item).media_filepath != nil
+    end
+
+    test "it saves the metadata to the media_item", %{media_item: media_item} do
+      expect(YtDlpRunnerMock, :run, fn _url, _opts, _ot ->
+        {:ok, render_metadata(:media_metadata)}
+      end)
+
+      assert media_item.metadata == nil
+      perform_job(MediaDownloadWorker, %{id: media_item.id})
+      assert Repo.reload(media_item).metadata != nil
+    end
+
+    test "it won't double-schedule downloading jobs", %{media_item: media_item} do
+      Oban.insert(MediaDownloadWorker.new(%{id: media_item.id}))
+      Oban.insert(MediaDownloadWorker.new(%{id: media_item.id}))
+
+      assert [_] = all_enqueued(worker: MediaDownloadWorker)
+    end
+
+    test "it sets the job to retryable if the download fails", %{media_item: media_item} do
+      expect(YtDlpRunnerMock, :run, fn _url, _opts, _ot -> {:error, "error"} end)
+
+      Oban.Testing.with_testing_mode(:inline, fn ->
+        {:ok, job} = Oban.insert(MediaDownloadWorker.new(%{id: media_item.id}))
+
+        assert job.state == "retryable"
+      end)
+    end
+
+    test "it does not download if the source is set to not download", %{media_item: media_item} do
+      expect(YtDlpRunnerMock, :run, 0, fn _url, _opts, _ot -> :ok end)
+
+      Sources.update_source(media_item.source, %{download_media: false})
+
+      perform_job(MediaDownloadWorker, %{id: media_item.id})
+    end
+
+    test "it schedules a filesystem data worker", %{media_item: media_item} do
+      expect(YtDlpRunnerMock, :run, fn _url, _opts, _ot ->
+        {:ok, render_metadata(:media_metadata)}
+      end)
+
+      assert [] = all_enqueued(worker: FilesystemDataWorker)
+
+      perform_job(MediaDownloadWorker, %{id: media_item.id})
+
+      assert [_] = all_enqueued(worker: FilesystemDataWorker)
+    end
+  end
+end