Redo indexing mechanism (#16)

* Bumped up the line length because I fear no man

* Refactored indexing

Previously, indexing worked by collecting the video IDs of only videos
that matched indexing criteria. This new model instead stores ALL videos
for a given source, but will only _download_ videos that meet that criteria.
This lets us backfill without indexing, makes it easier to add in other
backends, lets us download one-off videos for a source that don't quite
meet criteria, you name it.

* Updated media finders to respect format filters; Added credo file

lib/pinchflat/media.ex

@@ -19,15 +19,31 @@ defmodule Pinchflat.Media do
 
   @doc """
   Returns a list of pending media_items for a given source, where
-  pending means the `media_filepath` is `nil`.
+  pending means the `media_filepath` is `nil` AND the media_item
+  matches the format selection rules of the parent media_profile.
+
+  See `build_format_clauses` but tl;dr is it _may_ filter based
+  on shorts or livestreams depending on the media_profile settings.
 
   Returns [%MediaItem{}, ...].
   """
   def list_pending_media_items_for(%Source{} = source) do
-    from(
-      m in MediaItem,
-      where: m.source_id == ^source.id and is_nil(m.media_filepath)
-    )
+    media_profile = Repo.preload(source, :media_profile).media_profile
+
+    MediaItem
+    |> where([mi], mi.source_id == ^source.id and is_nil(mi.media_filepath))
+    |> where(^build_format_clauses(media_profile))
+    |> Repo.all()
+  end
+
+  @doc """
+  Returns a list of downloaded media_items for a given source.
+
+  Returns [%MediaItem{}, ...].
+  """
+  def list_downloaded_media_items_for(%Source{} = source) do
+    MediaItem
+    |> where([mi], mi.source_id == ^source.id and not is_nil(mi.media_filepath))
     |> Repo.all()
   end
 
@@ -72,4 +88,39 @@ defmodule Pinchflat.Media do
   def change_media_item(%MediaItem{} = media_item, attrs \\ %{}) do
     MediaItem.changeset(media_item, attrs)
   end
+
+  defp build_format_clauses(media_profile) do
+    mapped_struct = Map.from_struct(media_profile)
+
+    Enum.reduce(mapped_struct, dynamic(true), fn attr, dynamic ->
+      case {attr, media_profile} do
+        {{:shorts_behaviour, :only}, %{livestream_behaviour: :only}} ->
+          dynamic([mi], ^dynamic and (mi.livestream == true or fragment("? ILIKE ?", mi.original_url, "%/shorts/%")))
+
+        # Technically redundant, but makes the other clauses easier to parse
+        # (redundant because this condition is the same as the condition above, just flipped)
+        {{:livestream_behaviour, :only}, %{shorts_behaviour: :only}} ->
+          dynamic
+
+        {{:shorts_behaviour, :only}, _} ->
+          # return records with /shorts/ in the original_url
+          dynamic([mi], ^dynamic and fragment("? ILIKE ?", mi.original_url, "%/shorts/%"))
+
+        {{:livestream_behaviour, :only}, _} ->
+          # return records with livestream: true
+          dynamic([mi], ^dynamic and mi.livestream == true)
+
+        {{:shorts_behaviour, :exclude}, %{livestream_behaviour: lb}} when lb != :only ->
+          # return records without /shorts/ in the original_url
+          dynamic([mi], ^dynamic and fragment("? NOT ILIKE ?", mi.original_url, "%/shorts/%"))
+
+        {{:livestream_behaviour, :exclude}, %{shorts_behaviour: sb}} when sb != :only ->
+          # return records with livestream: false
+          dynamic([mi], ^dynamic and mi.livestream == false)
+
+        _ ->
+          dynamic
+      end
+    end)
+  end
 end